交易指令示例-2

白吉馍

该交易系统的建仓条件为： 1、前两个Bar收阳，并呈上涨趋势；
2、当前价格为最近前2个Bar最高价的回落，而且回落幅度大于0.382。回落幅度是相对于最高价到最低价的范围。
该交易系统的平仓条件为：
1、当前价格的获利价格点数大于建仓时最低价到最低价的范围。
该交易系统的止损条件为：
1、当前价格从建仓时的最高价格的回落大于最低价到最高价的范围的0.5。
Params
    Numeric TrailingSet(0.382);       // 回撤开仓比例设置，从最高点下跌的比例
    Numeric StopLossSet(0.5);        // 止损比例设置
Vars
    Bool startCondition(False);         // 启动条件
    Bool EntryCondition(False);        // 开仓条件
    Bool ExitCondition(False);          // 平仓条件
    NumericSeries highestValue(0);  // 前2个周期的最高价
    NumericSeries lowestValue(0);   // 前2个周期的最低价
    Numeric myEntryPrice(0);          // 开仓价格
    Numeric myExitPrice(0);            // 平仓价格        
Begin
    highestValue = highestValue[1];
    lowestValue = lowestValue[1];
    If(MarketPosition ==0 ) // 当前空仓
    {
        If(Close[2]>Open[2] && Close[1] > Open[1] && Close[1] > Close[2])
        {
            startCondition = True;
            highestValue = max(high[2],high[1]);
            lowestValue = min(low[2],low[1]);
        }
        
        If(startCondition)
        {
            EntryCondition = ((highestValue - Open) / (highestValue - lowestValue) > TrailingSet )&& // 开盘价即满足回撤条件，用开盘价进行交易
            (Open > highestValue -((highestValue - lowestValue)*StopLossSet)) ; //  开盘价不能低于预设的止损价                                                
            If( EntryCondition)
            {
                Buy(1,Open);
            }Else // 再看其它价格是否满足
            {
                EntryCondition = (highestValue - Low) / (highestValue - lowestValue) > TrailingSet ; // 最低价满足回撤条件,用低于TrailingSet设置的最近价位建仓
                If(EntryCondition)
                {
                    myEntryPrice = highestValue - (HighestValue - LowestValue ) * TrailingSet;
                    myEntryPrice = IntPart(myEntryPrice / (PriceScale()*MinMove)) *(PriceScale()*MinMove); // 对价格进行处理                                       
                    If(myEntryPrice >= low &&  myEntryPrice <= High)
                    {
                        Buy(1,MyEntryPrice);
                    }
                }                        
            }
        }
    }else If(MarketPosition == 1) // 当前多仓
    {
        ExitCondition = ( HighestValue - Low )/(highestValue - lowestValue) > StopLossSet;        // 止损条件满足
        If(ExitCondition)
        {
            myExitPrice =  highestValue - (HighestValue - LowestValue ) * StopLossSet;                        
            myExitPrice = IntPart(myExitPrice / (PriceScale()*MinMove)) *(PriceScale()*MinMove); // 对价格进行处理
            Sell(0,myExitPrice);
        }Else // 获利平仓
        {
            ExitCondition = (high - BuyEntryPrice()) > (highestValue - lowestValue); // 获利平仓条件满足
            If(ExitCondition)
            {
                myExitPrice =  BuyEntryPrice() + (HighestValue - LowestValue );                                
                myExitPrice = IntPart(myExitPrice / (PriceScale()*MinMove)) *(PriceScale()*MinMove); // 对价格进行处理
                If (myExitPrice >= low && myEntryPrice <= high)
                {
                    Sell(0,myExitPrice);
                }Else
                {
                    Sell(0,Close);
                }
            }
        }
    }
End

rzncq

客服壹号服务不错 赞一个！！！

kuang

坚持长期学习 坚持长期灌水

汤沛

这个好 很好

100

真的是好东西，谢谢分享了

老鱼

真的是好帖子啊，不错

sunyh

慢慢再看{:soso_e113:}

多伦多

{:soso_e179:}

多伦多

{:soso_e179:}

wqfeng

先顶后看.

期货可居

{:soso_e179:}

流年

{:soso_e100:}

风轻轻滴吹

我用在1分钟上，那个花。。。{:soso_e113:}

number

建议版主再发几个这样的例子供大家参考！

xisuhero

世上没有绝望的处境，只有对处境绝望的人。

看看..

baik924

{:soso_e192:}

sharewong

医生问病人是怎么骨折的。病人说，我觉得鞋里有沙子，就扶着电线杆抖鞋。TMD有个混蛋经过那里，以为我触电了，便抄起木棍给了我两棍子!　  

(*^__^*) 嘻嘻……